這篇文章主要為大家展示了“怎么用vbs實現獲取電腦硬件信息”，內容簡而易懂，條理清晰，希望能夠幫助大家解決疑惑，下面讓小編帶領大家一起研究并學習一下“怎么用vbs實現獲取電腦硬件信息”這篇文章吧。

創新互聯從2013年開始，是專業互聯網技術服務公司，擁有項目成都網站設計、成都網站建設網站策劃，項目實施與項目整合能力。我們以讓每一個夢想脫穎而出為使命，1280元利津做網站,已為上家服務,為利津各地企業和個人服務,聯系電話:028-86922220

代碼一：

'******************************************************************************************* 
 'Version:3.1 
 '   調整錯誤處理方法，錯誤信息輸出到LogFile文件，可以查看掃描失敗原因 
 '     如果出現“RPC 服務器不可用”錯誤，是因為遠程主機沒開機 
 '     如果出現“RPC 服務器不可用”之外的錯誤，可能是由于正在運行的程序造成，請你把此信息告訴我 
 '     重啟后再次掃描就可以排除非“RPC 服務器不可用。”的錯誤 
 '     如果掃描到的硬件信息為空，應該是驅動問題(或BIOS不完善)，請自行解決 
 'Version:3.0 
 '   增加輸出BIOS的發行日期，和主板信息放在一起 
 'Version:2.9 
 '   修正所有GetInfo過程遇錯的處理方法,避免返回的數組上限不符合輸出要求導致腳本報錯。 
 '     之所以為出現這種情況，是因為Win32類檢索不到硬件或連接到Win32類失敗； 
 '     原來判斷是否出現Err，忽略了檢索不到硬件的情況(連接成功無Err,Count為0) 
 '     檢索不到硬件多數是因為驅動沒裝好 
 'Version:2.8 
 '   增加GetIDEProtocol過程，獲取IDE控制器使用的協議，只是增加了代碼，沒有調用 
 '   計劃增加檢索其它存儲器控制器的過程 
 'Version:2.7 
 '   檢索硬盤/顯卡/網卡/聲卡的過程增加 DeviceID 屬性(設備標識符) 
 '     此屬性不被輸出，用于腳本內部判斷 
 'Version:2.6 
 '   原來輸出搜索到的第一個硬盤 
 '   改為輸出搜索到的第一個InterfaceType屬性為IDE的硬盤的信息 
 'Version:2.5 
 '   增加Sort過程，排序硬件信息 
 'Version:2.4 
 '   調整輸出信息的分類，同類信息盡可能的只使用一個逗號分隔，以便導入xls后在同一列 
 '   查詢到的硬件信息如果是空或0，有可能是相關驅動不完善或未定義此信息，也可能是未安裝驅動 
 '   因為WMI查詢就代表了系統知道這些硬件的詳細信息，查不到信息就是系統不知道 
 '   系統不知道硬件的詳細信息，代表著性能可能有所缺失，建議找個好驅動安裝 
 '   值得注意的是主板驅動 
 '   (為了更容易理解，此版本的升級信息被編輯過) 
 'Version:2.3 
 '   取消2.2版增加輸出的硬盤接口類型 
 '     由于STAT也歸于IDE接口，這會導致誤解 
 '     PS：腳本只輸出搜索到的第一個硬盤 
 'Version:2.2 
 '   GetMemoryInfo過程增加MemoryType、FormFactor、TypeDetail三個屬性 
 '     輸出增加內存類型、封裝類型 
 '     輸出增加硬盤容量、接口類型 
 'Version:2.1 
 '   GetOSInfo過程增加去掉Caption屬性中帶有的逗號“,”的代碼 
 '     原因：在檢測2003系統時，讀取到的Caption屬性，帶有逗號“,” 
 '     這會影響輸出，因為輸出是以逗號“,”為分隔符的 
 'Version:2.0 B5發布版 
 '   GetNetworkInfo過程改為使用MACAddress屬性非空、 
 '     Manufacturer屬性非"Microsoft"判斷網卡 
 'Version:2.0 Beta4 
 '   GetNetworkInfo過程使用NetConnectionStatus屬性判斷網絡適配器 
 '     NetConnectionStatus屬性表明連接狀態(2000系統不支持此屬性) 
 '     物理網絡適配器才具有此狀態(包括停用狀態在內) 
 'Version:2.0 Beta3 
 '   GetNetworkInfo過程增加一個判斷 
 '     忽略讀取IPAddress(0)時會產生Err類型數據的適配器(對戰平臺) 
 'Version:2.0 Beta2 
 '   GetOSInfo過程原來使用的Name、ServicePackMajorVersion屬性 
 '     改為使用Caption、CSDVersion屬性 
 '   所有GetInfo過程增加錯誤處理代碼，避免正在掃描的時候 
 '     腳本遇到運行時錯誤導致腳本退出 
 'Version:2.0 Beta1 
 '   增加掃描失敗記錄，再次運行腳本只讀取失敗記錄，忽略配置信息 
 'Version:1.1 
 '   GetNetworkInfo過程增加一個判斷 
 '     忽略NetConnectionID屬性(接口名稱)為空的適配器 
 'Version:1.0 
 '   初始版本 

 Option Explicit 
  
 '********************************說明開始************************************* 
 'Input格式：起始IP-數量=用戶名=密碼;起始計算機名-數量=用戶名=密碼 
 '       多個配置項用“;”隔開 
 '例：192.168.0.1-10指明IP范圍為192.168.0.1~192.168.0.10，支持跨網段 
 '例：PC001-10指明范圍為PC001~PC010(計算機名可以包含-號) 
 '與指定格式不相同的，默認為單IP[計算機名],也可以在"未掃描的計算機.txt"里配置 
 '"硬件信息.txt"是以逗號分隔各項硬件信息，你需要自己導入XLS整理、精簡 
 '未掃描到的計算機，會把機號、用戶名、密碼保存到"未掃描的計算機.txt" 
 '再次運行腳本將只讀取"未掃描的計算機.txt"里的信息(如果存在并且大小不為0) 
 '********************************說明結束************************************* 
  
 Dim Input, InfoOutFile, LogFile '請按格式給Input賦值 
 'Input = "pc021=administrator=cylslynetbar" 
 Input = "PC001-109=administrator=cylslynetbar;pc110-85=administrator=LYjfnetbaradmin" 
 InfoOutFile = "硬件信息.txt" 
 LogFile = "未掃描的計算機.txt" 
  
 Redim arrConfig(0) 
 Dim WshShell, FSO, intCount1, intCount2 
 intCount1 = 0 
 intCount2 = 0 
 Set WshShell = WScript.CreateObject("WScript.Shell") 
 Set FSO = WScript.Createobject("Scripting.Filesystemobject") 
 ReadConfig 
 WshShell.Popup "掃描過程會很慢，請耐心等待，完成后會給出提示",,"掃描開始" 
 LinkRemoteServer arrConfig 
 Dim LenNum1, LenNum2 
 If intCount1 > intCount2 Then 
  LenNum1 = 0 
  LenNum2 = Len(intCount1) - Len(intCount2) 
 Else 
  LenNum1 = Len(intCount2) - Len(intCount1) 
  LenNum2 = 0 
 End If 
 Sort InfoOutFile 
 WshShell.Popup "掃描結果：" & _ 
         vbCrLf & vbTab & "掃描成功：" & Space(LenNum1) & intCount1 & " 臺" & _ 
         vbCrLf & vbTab & "掃描失敗：" & Space(LenNum2) & intCount2 & " 臺" & _ 
         vbCrLf & "掃描失敗的電腦已做記錄，再次運行腳本只掃描記錄里的電腦",,"掃描完成" 
  
Function ReadConfig 
 Dim objMatches, objMatche,objLogFile, arrLog, intUBarrConfig 
 If FSO.FileExists(LogFile) Then 
  If FSO.GetFile(LogFile).Size = 0 Then 
   Set objMatches = GetMatche("([^;=]+)=([^;=]+)=([^;=]+)", Input) 
   For Each objMatche In objMatches 
    GetConfig objMatche.SubMatches(0), objMatche.SubMatches(1), objMatche.SubMatches(2) 
   Next 
   If objMatches.Count = 0 Then 
    Msgbox "配置信息格式不正確，請修改" 
    WScript.Quit 
   End If 
  Else 
   Set objLogFile = FSO.OpenTextFile(LogFile) 
   Do Until objLogFile.AtEndOfStream 
    arrLog = Split(objLogFile.ReadLine,"=") 
    intUBarrConfig = ((Ubound(arrConfig)+1)\3+1)*3-1 
    Redim Preserve arrConfig(intUBarrConfig) 
    arrConfig(intUBarrConfig-2) = arrLog(0) 
    arrConfig(intUBarrConfig-1) = arrLog(1) 
    arrConfig(intUBarrConfig-0) = arrLog(2) 
   Loop 
  End If 
 Else 
  Set objMatches = GetMatche("([^;=]+)=([^;=]+)=([^;=]+)", Input) 
  For Each objMatche In objMatches 
   GetConfig objMatche.SubMatches(0), objMatche.SubMatches(1), objMatche.SubMatches(2) 
  Next 
  If objMatches.Count = 0 Then 
   Msgbox "配置信息格式不正確，請修改" 
   WScript.Quit 
  End If 
 End If 
End Function 


'********************************************************************************* 
'目的：連接到遠程主機的WMI命名空間 
'輸入：arrArray數組，包含有計算機名[IP]、用戶名、密碼 
'調用：LinkServer過程 
'    如果返回SWbemLocator對象ConnectServer方法的實例，調用OutInfo過程 
'    如果返回Err信息(字符串類型)，輸出計算機名[IP]、用戶名、密碼及錯誤信息到LogFile文件 
'   OutInfo過程 
'    如果返回Err信息(字符串類型)輸出計算機名[IP]、用戶名、密碼及錯誤信息到LogFile文件 
'傳遞：SWbemLocator對象ConnectServer方法的實例傳遞給OutInfo過程 
'   計算機名[IP]、命名空間、用戶名、密碼傳遞給LinkServer過程 
'********************************************************************************* 
Function LinkRemoteServer(arrArray) 
 Dim objErrLog, E, objLinkServer, objConnection, objWbemLocator, objErr 
 Set objWbemLocator = CreateObject("WbemScripting.SWbemLocator") 
 Set objErrLog = FSO.CreateTextFile(LogFile,True) 
 For E = 0 To Ubound(arrArray) Step 3 
  Set objLinkServer = LinkServer(arrConfig(E),"root\cimv2",arrConfig(E+1),arrConfig(E+2)) 
  If Err Then 
   objErrLog.Writeline arrArray(E) & "=" & arrArray(E+1) & "=" & arrArray(E+2) & "=" & _ 
             "錯誤編號：" & CStr(Err.Number) & _ 
             "，錯誤原因：" & CStr(Err.Description) & _ 
             "，錯誤來源：" & CStr(Err.Source) & " By LinkServer Function" 
   intCount2 = intCount2 + 1 
   Err.Clear 
  Else 
   objErr = OutInfo(objLinkServer) 
   If Vartype(objErr) = 8 Then 
    objErrLog.Writeline arrArray(E) & "=" & arrArray(E+1) & "=" & arrArray(E+2) & "=" & objErr 
    intCount2 = intCount2 + 1 
   End If 
  End If 
 Next 
End Function 

'****************************************************** 
'目的：輸出硬件信息 
'輸入：SWbemLocator對象ConnectServer方法的實例 
'調用：獲取硬件信息的GetXXXInfo過程 
'傳遞：SWbemLocator對象ConnectServer方法的實例 
'返回：所有調用的GetInfo過程都未返回Err對象，則返回True 
'   某個GetInfo過程返回Err對象，則返回False 
'****************************************************** 
Function OutInfo(objRemote) 
 Dim OutFile, arrInfo, strOutInfo, Tmp, A 
 If FSO.FileExists(InfoOutFile) Then 
  Set OutFile = FSO.OpenTextFile(InfoOutFile,8) 
 Else 
  Set OutFile = FSO.CreateTextFile(InfoOutFile) 
  OutFile.Writeline "計算機名,系統(初裝日期),主板型號(廠商)(發行日期),CPU型號(接口類型),外頻,L2容量(速度)," & _ 
           "內存總量,內存速度(位置),內存類型(封裝類型),硬盤型號(容量),顯卡型號(顯存),網卡,IP/MAC" 
 End If 
 '系統 
 arrInfo = GetOSInfo(objRemote) 
 If Vartype(arrInfo) = 8 Then 
  OutInfo = arrInfo 
  Exit Function 
 End If 
 strOutInfo = arrInfo(0) & "," & arrInfo(1) & "(" & arrInfo(2) & ")," 
 '主板 
 arrInfo = GetBoardInfo(objRemote) 
 If Vartype(arrInfo) = 8 Then 
  OutInfo = arrInfo 
  Exit Function 
 End If 
 strOutInfo = strOutInfo & arrInfo(0) & "(" & arrInfo(1) & ")" 
 'BIOS 
 arrInfo = GetBIOSInfo(objRemote) 
 If Vartype(arrInfo) = 8 Then 
  OutInfo = arrInfo 
  Exit Function 
 End If 
 strOutInfo = strOutInfo & "(" & arrInfo(2) & ")," 
 'CPU 
 arrInfo = GetCPUInfo(objRemote) 
 If Vartype(arrInfo) = 8 Then 
  OutInfo = arrInfo 
  Exit Function 
 End If 
 strOutInfo = strOutInfo & arrInfo(1) & "(" & arrInfo(8) & ")," & arrInfo(4) & "," & _ 
        arrInfo(6) & "(" & arrInfo(7) & ")," 
 '內存 
 arrInfo = GetMemoryInfo(objRemote) 
 If Vartype(arrInfo) = 8 Then 
  OutInfo = arrInfo 
  Exit Function 
 End If 
 Tmp = 0 
 For A = 1 To Ubound(arrInfo) Step 6 
  Tmp = Tmp + Cint(arrInfo(A)) 
 Next 
 strOutInfo = strOutInfo & arrInfo(0) & "條，共" & Tmp & "M," 
 Tmp = "" 
 For A = 2 To Ubound(arrInfo) Step 6 
  If A = Ubound(arrInfo) - 4 Then 
   Tmp = Tmp & arrInfo(A) & "(" & arrInfo(A+1) & ")," 
  Else 
   Tmp = Tmp & arrInfo(A) & "(" & arrInfo(A+1) & ") " 
  End If 
 Next 
 strOutInfo = strOutInfo & Tmp 
 Tmp = "" 
 For A = 4 To Ubound(arrInfo) Step 6 
  If A = Ubound(arrInfo) - 2 Then 
   Tmp = Tmp & arrInfo(A) & "(" & arrInfo(A+1) & ")," 
  Else 
   Tmp = Tmp & arrInfo(A) & "(" & arrInfo(A+1) & ") " 
  End If 
 Next 
 strOutInfo = strOutInfo & Tmp 
 '硬盤 
 Tmp = "" 
 arrInfo = GetDiskInfo(objRemote) 
 If Vartype(arrInfo) = 8 Then 
  OutInfo = arrInfo 
  Exit Function 
 End If 
 For A = 1 To Ubound(arrInfo) Step 5 
  If arrInfo(A+1) = "IDE" Then 
   Tmp = arrInfo(A) & "(" & arrInfo(A+2) & "G)," 
   Exit For 
  End If 
 Next 
 If Tmp = "" Then 
  strOutInfo = strOutInfo & "硬盤型號未檢索到," 
 Else 
  strOutInfo = strOutInfo & Tmp 
 End If 
 '顯卡 
 arrInfo = GetVideoInfo(objRemote) 
 If Vartype(arrInfo) = 8 Then 
  OutInfo = arrInfo 
  Exit Function 
 End If 
 strOutInfo = strOutInfo & arrInfo(0) & "(" & arrInfo(1) & "M)," 
 '網卡 
 arrInfo = GetNetworkInfo(objRemote) 
 If Vartype(arrInfo) = 8 Then 
  OutInfo = arrInfo 
  Exit Function 
 End If 
 strOutInfo = strOutInfo & arrInfo(1) & "," & arrInfo(2) & Space(17-Len(arrInfo(2))) & arrInfo(3) 
 '輸出 
 OutFile.Writeline strOutInfo 
 intCount1 = intCount1 + 1 
 OutInfo = True 
End Function 

'********************************************************* 
'目的：連接到遠程主機的WMI命名空間 
'輸入：strComputer：遠程主機的計算機名或IP 
'   strNamespace：命令空間 
'   strUserName：用戶名 
'   strPassword：密碼 
'返回：連接成功，返回SWbemLocator類連接遠程主機后的對象的實例 
'   連接失敗，返回錯誤對象 
'********************************************************* 
Function LinkServer(strComputer,strNamespace,strUserName,strPassword) 
 Dim objWbemLocator 
 Set objWbemLocator = CreateObject("WbemScripting.SWbemLocator") 
 Dim objConnection 
 On Error Resume Next 
 Set objConnection = objwbemLocator.ConnectServer _ 
           (strComputer, strNamespace, strUserName, strPassword) 
 If Err Then 
   Set LinkServer = Err 
   Exit Function 
 End If 
 On Error Goto 0 
 objConnection.Security_.ImpersonationLevel = 3 
 Set LinkServer = objConnection 
End Function 

'****************************************** 
'目的：正則表達式 
'輸入：strPatrn：正則表達式模式 
'   strString：要執行正則表達式的字符串 
'返回：Match對象 
'****************************************** 
Function GetMatche(strPatrn, strString) 
 Dim RegEx 
 Set RegEx = New Regexp 
 RegEx.Global = True 
 RegEx.IgnoreCase =True 
 RegEx.Pattern = strPatrn 
 Set GetMatche = RegEx.Execute(strString) 
End Function 

'*************************************** 
'目的：2、8、16進制轉10進制 
'輸入：strString：2、8、16進制數 
'   intNum：進制(2|8|16) 
'返回：10進制數 
'*************************************** 
Function ChangeToDecimal(strString, intNum) 
 ChangeToDecimal = 0 
 If Isnull(strString) Then ChangeToDecimal = 0 : Exit Function 
 Dim A, M 
 For A = 1 To Len(strString) 
  M = LCase(Mid(strString, A, 1)) 
  Select Case M 
   Case "a" :M = 10 
   Case "b" :M = 11 
   Case "c" :M = 12 
   Case "d" :M = 13 
   Case "e" :M = 14 
   Case "f" :M = 15 
  End Select 
  ChangeToDecimal = ChangeToDecimal + M * intNum^(Len(strString)-A) 
 Next 
End Function

以上是“怎么用vbs實現獲取電腦硬件信息”這篇文章的所有內容，感謝各位的閱讀！相信大家都有了一定的了解，希望分享的內容對大家有所幫助，如果還想學習更多知識，歡迎關注創新互聯行業資訊頻道！

名稱欄目：怎么用vbs實現獲取電腦硬件信息-創新互聯
本文網址：http://m.newbst.com/article6/hsgig.html

成都網站建設公司_創新互聯，為您提供網站維護、做網站、網站收錄、動態網站、品牌網站制作、自適應網站

廣告

聲明：本網站發布的內容（圖片、視頻和文字）以用戶投稿、用戶轉載內容為主，如果涉及侵權請盡快告知，我們將會在第一時間刪除。文章觀點不代表本網站立場，如需處理請聯系客服。電話：028-86922220；郵箱：631063699@qq.com。內容未經允許不得轉載，或轉載時需注明來源： 創新互聯